MeasureCollectRawData Function

Action

Enables the collection of raw measure data for the measure identified by sName and eType. Raw measure data will be stored in CSV files in the result directory of the corresponding load test.

Include file

Kernel.bdh

Syntax

MeasureCollectRawData( in bEnable : boolean,
                       in sName   : string optional,
                       in eType   : number optional ): boolean;

Parameter	Description
bEnable	true/false
sName	The measure name
eType	Specifies the measure type: MEASURE_IIOP_ROUNDTRIP MEASURE_IIOP_SERVERBUSY MEASURE_TIMER_RESPONSETIME MEASURE_COUNTER_CUSTOMCOUNTER MEASURE_SQL_SQLPARSE MEASURE_SQL_SQLEXEC MEASURE_SQL_SQLEXECDIRECT MEASURE_TRANS_TRANSOK MEASURE_TRANS_TRANSERR MEASURE_TRANS_TRANSCA MEASURE_FORM_BYTESSENT MEASURE_FORM_BYTESRECEIVED MEASURE_FORM_HITSOK MEASURE_FORM_HITSERR MEASURE_FORM_ROUNDTRIP MEASURE_FORM_SERVERBUSY MEASURE_TUXEDO_BYTESSENT MEASURE_TUXEDO_BYTESRECEIVED MEASURE_TUXEDO_RESPONSETIME MEASURE_COUNTER_AVERAGE MEASURE_PAGE_PAGETIME (for protocol-level load testing) MEASURE_PAGE_DOCDOWNLOAD MEASURE_PAGE_SERVERBUSY MEASURE_PAGE_PAGEBYTES MEASURE_PAGE_EMBEDDEDBYTES MEASURE_PAGE_ACTIONTIME (for browser-driven load testing) MEASURE_TRANS_TRANSBUSYOK MEASURE_TRANS_TRANSBUSYERR MEASURE_TRANS_TRANSBUSYCA

Return value

true if successful
false otherwise

Example

benchmark BenchmarkName
 
use "kernel.bdh" 
use "webapi.bdh"
 
dcluser  
  user
    VirtUser
  transactions
    TRawDataAll : 1;
    TRawDataName : 1;
    TRawDataType : 1;
    TRawDataNameType : 1;
                       
dcltrans  
  transaction TRawDataAll
  begin
    // enable generation of raw data for default measures
    MeasureCollectRawData(true);
    
    WebPageUrl("http://www.borland.com/"); // raw data will be collected    
  end TRawDataAll;
  
  transaction TRawDataName
  begin
    // enable generation of raw data for measures with specific name "MyMeasure"
    MeasureCollectRawData(true, "MyMeasure");
    
    WebPageUrl("http://www.borland.com/", "MyMeasure"); // raw data will be collected    
    WebPageUrl("http://demo.borland.com/", "MyWebSite"); // raw data will NOT be collected    
  end TRawDataName;
  
  transaction TRawDataType
  begin
    // enable generation of raw data for measures of type 
    MeasureCollectRawData(true, "", MEASURE_PAGE_EMBEDDEDBYTES);
    
    WebPageUrl("http://www.borland.com/", "MyMeasure"); // only raw data of type MEASURE_PAGE_EMBEDDEDBYTES will be collected
    WebPageUrl("http://demo.borland.com/", "MyWebSite"); // only raw data of type MEASURE_PAGE_EMBEDDEDBYTES will be collected
  end TRawDataType;
  
  transaction TRawDataNameType
  begin
    // enable generation of raw data for measures with specific name "MyMeasure" and of type MEASURE_PAGE_EMBEDDEDBYTES
    MeasureCollectRawData(true, "MyMeasure", MEASURE_PAGE_EMBEDDEDBYTES);
    
    WebPageUrl("http://www.borland.com/", "MyMeasure"); // only raw data of MEASURE_PAGE_EMBEDDEDBYTES will be collected
    WebPageUrl("http://demo.borland.com/", "MyWebSite"); // raw data will NOT be collected
  end TRawDataNameType;